bound03.f90

Go to the documentation of this file.

!> @file bound03.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! 
!! Model in which several simple inequalities are converted into simple
!! bounds. The implied bounds are infeasible
!! 
!! \f{eqnarray*}{
!! \min &sqr(x1-x2) \\
!! &x2      <=  4 \\
!! &x2      >=  3 \\
!! &x1      >=  1 \\
!! &2*x2      <=  5
!! \f}
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
!> Main program. A simple setup and call of CONOPT
!!
Program bound03
 
   Use proginfo
   Use coidef
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: bound_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: bound_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
   Integer, External :: std_triord     ! Standard callback for triangular order
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Bound_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Bound_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_TriOrd
#endif
!
!  Control vector
!
   INTEGER :: numcallback
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
 
   call startup
!
!  Create and initialize a Control Vector
!
   numcallback = coidef_size()
   Allocate( cntvect(numcallback) )
   coi_error = coidef_inifort( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 2 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 5 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 6 ) )  ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 2 ) )  ! # of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) ) ! Minimize
   coi_error = max( coi_error, coidef_objcon( cntvect, 5 ) )  ! Objective is constraint #
   coi_error = max( coi_error, coidef_optfile( cntvect, 'bound03.opt'  ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, bound_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, bound_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
   coi_error = max( coi_error, coidef_triord( cntvect, std_triord     ) )
 
#if defined(LICENSE_INT_1) && defined(LICENSE_INT_2) && defined(LICENSE_INT_3) && defined(LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, license_int_1, license_int_2, license_int_3, license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Bound03 example. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 4 ) then ! Inconsistent bounds give global infeasibility
      call flog( "Solver and Model Status was not as expected (1,4)", 1 )
   elseif ( abs( xprim(2)-uprim(1) ) > 1.d-7 ) then
      call flog( "Incorrect activity in row 1", 1 )
   elseif ( abs( xprim(2)-uprim(2) ) > 1.d-7 ) then
      call flog( "Incorrect activity in row 2", 1 )
   elseif ( abs( xprim(1)-uprim(3) ) > 1.d-7 ) then
      call flog( "Incorrect activity in row 3", 1 )
   elseif ( abs( 2*xprim(2)-uprim(4) ) > 1.d-7 ) then
      call flog( "Incorrect activity in row 4", 1 )
   elseif ( abs( (xprim(1)-xprim(2))**2-uprim(5) ) > 1.d-7 ) then
      call flog( "Incorrect activity in row 5", 1 )
   Else
      Call checkdual( 'Bound03', infeasible )
   endif
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
 
End Program bound03
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function bound_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Bound_ReadMatrix
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
!  The model uses defaults
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
   integer, parameter :: equal = 0, greater = 1, less = 2, nonbnd = 3
!
!  Constraint 1:
!
   rhs(1)  = 4.0d0
   type(1) = less
!
!  Constraint 2:
!
   rhs(2)  = 3.d0
   type(2) = greater
!
!  Constraint 3:
!
   rhs(3)  = 1.d0
   type(3) = greater
!
!  Constraint 4:
!
   rhs(4)  = 5.d0
   type(4) = less
!
!  Constraint 5:
!
   type(5) = nonbnd
!
!  Information about the Jacobian. We use the standard method with
!  Rowno, Value, Nlflag and Colsta and we do not use Colno.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x2      <=  4
!       x2      >=  3
!       x1      >=  1
!     2*x2      <=  5
!  min sqr(x1-x2)
!       x(1)  x(2)
!  1:          3
!  2:          4
!  3:    1
!  4:          5
!  5:    2     6
!
   colsta(1) =  1
   colsta(2) =  3
   colsta(3) =  7
   rowno(1)  =  3
   rowno(2)  =  5
   rowno(3)  =  1
   rowno(4)  =  2
   rowno(5)  =  4
   rowno(6)  =  5
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!       x(1)  x(2)
!  1:          L
!  2:          L
!  3:    L
!  4:          L
!  5:   NL    NL
!
   nlflag(1) =  0
   nlflag(2) =  1
   nlflag(3) =  0
   nlflag(4) =  0
   nlflag(5) =  0
   nlflag(6) =  1
!
!       x2      <=  4
!       x2      >=  3
!       x1      >=  1
!     2*x2      <=  5
!  min sqr(x1-x2)
!  Value (Linear only)
!       x(1)  x(2)
!  5:   NL    NL
!
   value(1)  =  1.d0
   value(3)  =  1.d0
   value(4)  =  1.d0
   value(5)  =  2.d0
 
  bound_readmatrix = 0 ! Return value means OK
 
end Function bound_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function bound_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                               n, nz, thread, usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Bound_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
!
!  Row 5 is nonlinear: sqr(x2-x1)
!
   if ( rowno .eq. 5 ) then
!
!  Mode = 1 or 3. G = sqr(x1-1)
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = (x(2)-x(1))*(x(2)-x(1))
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = -2.d0*(x(2)-x(1))
         jac(2) = +2.d0*(x(2)-x(1))
      endif
      bound_fdeval = 0
!
!  The other rows are linear and will not be called
!
   else
      bound_fdeval = 1
   endif
 
end Function bound_fdeval