cns03.f90

Go to the documentation of this file.

!> @file cns03.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! This is a CONOPT implementation of the GAMS model:
!! 
!! @verbatim
!! variable x1,x2,x3;
!! equation e1,e2;
!! 
!! e1 .. x1 =e= 5;
!! e2 .. x1 + x2 +x3 =e= 7;
!! 
!! x1.fx = 5;
!! 
!! model m / all /;
!! @endverbatim
!! 
!! * Case 1: with holdfixed=0, GAMS passes on a square 2x2 model
!!           in x2 and x3 - x1 is ignored since it is fixed
!! @verbatim
!! m.holdfixed = 0;
!! solve m using cns;
!! abort$(m.solvestat <> 1)                            'bad solvestat';
!! if   { (m.modelstat = 5),
!! * locally infeasible, should report a row that way
!! abort$(m.numinfes < 1)                            'wrong .numinfes';
!! * this next check may be too ambitious - we'll see how it flies
!! abort$(m.numdepnd < 1)                            'wrong .numdepnd';
!! elseif (m.modelstat = 17),
!! * solved singular, should indicate that one dependency exists
!! havesol = 1;
!! abort$(m.numdepnd <> 1)                           'wrong .numdepnd';
!! else
!! havesol = 1;
!! abort$(m.modelstat <> 16)                         'bad modelstat';
!! };
!! if {havesol,
!! abort$(abs(x2.l+x3.l-2) > tol)     'bad x2.l+x3.l';
!! abort$(abs(e1.l-5) > tol)          'bad e1.l';
!! abort$(abs(e2.l-7) > tol)          'bad e2.l';
!! };
!! @endverbatim
!! 
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
 
 
!> Main program. A simple setup and call of CONOPT
!!
Program cns03
 
   Use proginfo
   Use coidef
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: cns03_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Cns03_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER :: numcallback
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
 
   Logical :: havesol
!
!  Create and initialize a Control Vector
!
   call startup
 
   numcallback = coidef_size()
   Allocate( cntvect(numcallback) )
   coi_error = coidef_inifort( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 3 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 2 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 4 ) )  ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 0 ) )  ! # of which are nonlinear
   coi_error = max( coi_error, coidef_square( cntvect, 1 ) )  ! Square system
   coi_error = max( coi_error, coidef_optfile( cntvect, 'cns03.opt'    ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, cns03_readmatrix ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(LICENSE_INT_1) && defined(LICENSE_INT_2) && defined(LICENSE_INT_3) && defined(LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, license_int_1, license_int_2, license_int_3, license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   havesol = .false.
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 ) then
      call flog( "Solver Status was not 1 as expected.", 1 )
   else
      if ( mstat == 5 ) then ! Locally infeasible
         if ( c_infeas == 0 ) then
            call flog( "Mstat = 5 and Count of infeasibilities was not positive.", 1 )
         elseif ( c_nonopt == 0 ) then ! Dependencies are flagged as non-optimal.
            call flog( "Mstat = 4 and Count of dependencies was not positive.", 1 )
         endif
      elseif ( mstat == 17 ) then ! solved singular
         if ( c_infeas /= 0 ) then
            call flog( "Mstat = 17 and Count of infeasibilities was not zero.", 1 )
         elseif ( c_nonopt == 0 ) then ! Dependencies are flagged as non-optimal.
            call flog( "Mstat = 17 and Count of dependencies was not positive.", 1 )
         endif
         havesol = .true.
      elseif ( mstat == 16 ) then ! Solved
         havesol = .true.
      Else
         call flog( "Model Status was not as expected 5, 16, or 17.", 1 )
      endif
   endif
   if ( havesol ) then
      if ( abs(xprim(2)+xprim(3)-2.0d0) > 1.d-8 ) then
         call flog( "Bad levels for x2 + x3.", 1 )
      else if ( abs(uprim(1)-5.0d0) > 1.d-8 ) then
         call flog( "Bad e1 level.", 1 )
      else if ( abs(uprim(2)-7.0d0) > 1.d-8 ) then
         call flog( "Bad e2 level.", 1 )
      endif
   Endif
 
   write(*,*)
   write(*,*) 'End of Cns03 example. Return code=',coi_error
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
 
End Program cns03
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function cns03_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Cns03_ReadMatrix
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
   lower(1) = 5.0d0
   upper(1) = 5.0d0
   curr(1)  = 5.0d0
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
   type(1) = 0
   rhs(1)  = 5.0d0
   type(2) = 0
   rhs(2)  = 7.0d0
!
!  Information about the Jacobian. We use the standard method with
!  Rowno, Value, Nlflag and Colsta and we do not use Colno.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)  x(2)  x(3)
!  1:    1
!  2:    2     3     4
!
   colsta(1) =  1
   colsta(2) =  3
   colsta(3) =  4
   colsta(4) =  5
   rowno(1)  =  1
   rowno(2)  =  2
   rowno(3)  =  2
   rowno(4)  =  2
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!  Not reported for a linear model
!       x(1)  x(2)  x(3)
!  1:    L
!  2:    L     L     L
!
!   nlflag(1) =  0
!   nlflag(2) =  0
!   nlflag(3) =  0
!   nlflag(4) =  0
!
!  Value (Linear only)
!       x(1)  x(2)   x(3)
!  1:    1
!  2:    1     1      1
!
   value(1)  =  1.0d0
   value(2)  =  1.0d0
   value(3)  =  1.0d0
   value(4)  =  1.0d0
 
  cns03_readmatrix = 0 ! Return value means OK
 
end Function cns03_readmatrix