cns12.f90

Go to the documentation of this file.

!> @file cns12.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! This is a CONOPT implementation of the GAMS model:
!!
!!
!! @verbatim
!! $if not set TESTTOL $set TESTTOL 1e-6
!! scalar tol / %TESTTOL% /;
!!
!! Scalar scale / 1 /;
!!
!! variable x1, x2, x3;
!! equation e1, e2, e3;
!!
!! e1 .. scale * x1 * x2 =e= scale;
!! e2 .. x2 + x3 =e= 0;
!! e3 .. x2 - x3 =e= 0;
!!
!! x1.l = 1;
!! x2.l = 1;
!! x3.l = 1;
!!
!! model m / all /;
!! @endverbatim
!!
!!
!! *  Case 1: without bounds, a solver may get within tolerance with
!!            a large x1 and small x2,x3
!! @verbatim
!! x1.l = 1; x2.l = 1; x3.l = 1;
!! solve m using cns;
!! abort$(m.solvestat <> 1                    )  'bad solvestat';
!! if {(m.modelstat = 16),
!! * solver found a "solution": check that it is within tolerance
!! abort$(abs(e1.l-scale) > tol)                   'bad e1.l';
!! abort$(abs(e2.l-0) > tol)                       'bad e2.l';
!! abort$(abs(e3.l-0) > tol)                       'bad e3.l';
!! else
!! abort$(m.modelstat <> 5)                        'bad modelstat';
!! abort$(m.numinfes < 1)                          'wrong .numinfes';
!! };
!! @endverbatim
!!
!! *  Case 2: bound x2, this makes the model infeasible
!! @verbatim
!! x1.lo = -1e5; x1.up = 1e5;
!! x1.l = 1; x2.l = 1; x3.l = 1;
!! solve m using cns;
!! abort$(m.solvestat <> 1 or m.modelstat <> 5)      'bad return codes';
!! abort$(m.numinfes < 1)                            'wrong .numinfes';
!! x1.lo = -INF; x1.up = INF;
!! @endverbatim
!!
!!
!! *  Case 3: scaled version of case 1
!! @verbatim
!! scale = 5;
!! x1.l = 1; x2.l = 1; x3.l = 1;
!! solve m using cns;
!! abort$(m.solvestat <> 1                    )      'bad solvestat';
!! if {(m.modelstat = 16),
!! * solver found a "solution": check that it is within tolerance
!! abort$(abs(e1.l-scale) > tol)                   'bad e1.l';
!! abort$(abs(e2.l-0) > tol)                       'bad e2.l';
!! abort$(abs(e3.l-0) > tol)                       'bad e3.l';
!! else
!! abort$(m.modelstat <> 5)                        'bad modelstat';
!! abort$(m.numinfes < 1)                          'wrong .numinfes';
!! };
!! @endverbatim
!!
!!
!! *  Case 4: bound x2, this makes the model infeasible
!! @verbatim
!! scale = 5;
!! x1.lo = -1e5; x1.up = 1e5;
!! x1.l = 1; x2.l = 1; x3.l = 1;
!! solve m using cns;
!! abort$(m.solvestat <> 1 or m.modelstat <> 5)      'bad return codes';
!! abort$(m.numinfes < 1)                            'wrong .numinfes';
!! x1.up = INF;
!! x1.lo = -INF; x1.up = INF;
!! @endverbatim
!!
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
!> Main program. A simple setup and call of CONOPT
!!
Program cns12
 
   Use proginfo
   Use conopt
   Use casedata_num
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: cns12_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: cns12_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Cns12_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Cns12_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
!
!  Solution info
!
   real*8 tol
   tol = 1.d-16
!
!  Create and initialize a Control Vector
!
   call startup
 
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 3 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 3 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 6 ) )  ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 2 ) )  ! # of which are nonlinear
   coi_error = max( coi_error, coidef_square( cntvect, 1 ) )  ! Square system
   coi_error = max( coi_error, coidef_optfile( cntvect, 'cns12.opt'    ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, cns12_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, cns12_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   casenum = 1; scale = 1.d0
   coi_error = coi_solve( cntvect )
 
   If ( coi_error /= 0 ) then
      call flog( "Case 1: Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Case 1: Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 ) then
      call flog( "Case 1: Solver Status was not 1 as expected.", 1 )
   else
      if ( mstat == 16 ) then ! Solved
! * solver found a "solution": check that it is within tolerance
!   abort$(abs(e1.l-scale) > tol)                   'bad e1.l';
         if ( abs(uprim(1)-scale)>tol ) then
            call flog( "Case 1: Bad e1 level.", 1 )
!   abort$(abs(e2.l-0) > tol)                       'bad e2.l';
         else if ( abs(uprim(2)-0)>tol ) then
            call flog( "Case 1: Bad e2 level.", 1 )
!   abort$(abs(e3.l-0) > tol)                       'bad e3.l';
         else if ( abs(uprim(3)-0)>tol ) then
            call flog( "Case 1: Bad e3 level.", 1 )
         endif
      else if ( mstat /= 5 ) then ! Locally infeasible
         call flog( "Case 1: Model Status was not as expected either 5 or 16.", 1 )
      else if ( c_infeas == 0 ) then
         call flog( "Case 1: Infeasibility count was zero.", 1 )
      endif
   endif
 
#if defined (notfinished)
   casenum = 2
   coi_error = coi_solve( cntvect )
 
   If ( coi_error /= 0 ) then
      call flog( "Case 2: Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Case 2: Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 16 ) then
      call flog( "Case 2: Solver and Model Status was not as expected (1,16)", 1 )
   else
      ok = ( abs(xprim(1)-x1) < tol .and. abs(xprim(2)-y1) < tol ) .or. &
           ( abs(xprim(1)-x2) < tol .and. abs(xprim(2)-y2) < tol )
      if ( .not. ok ) then
         write(10,*) 'Solution for case 2 was x=',xprim(1),' and y=',xprim(2)
         call flog( "Case 2: Solver values were not correct.", 1 )
      endif
   endif
 
   casenum = 3
   coi_error = coi_solve( cntvect )
 
   If ( coi_error /= 0 ) then
      call flog( "Case 3: Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Case 3: Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 16 ) then
      call flog( "Case 3: Solver and Model Status was not as expected (1,16)", 1 )
   else
      ok = ( abs(xprim(1)-x1) < tol .and. abs(xprim(2)-y1) < tol )
      if ( .not. ok ) then
         write(10,*) 'Solution for case 3 was x=',xprim(1),' and y=',xprim(2)
         call flog( "Case 3: Solver values were not correct.", 1 )
      endif
   endif
 
   casenum = 4
   coi_error = coi_solve( cntvect )
 
   If ( coi_error /= 0 ) then
      call flog( "Case 4: Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Case 4: Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 5 ) then
      call flog( "Case 4: Solver and Model Status was not as expected (1,5)", 1 )
   elseif ( c_infeas == 0 ) then
      call flog( "Case 4: Infeasibility count is zero.", 1 )
   endif
#endif
 
   write(*,*)
   write(*,*) 'End of Cns12 example. Return code=',coi_error
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
!
!  Free solution memory
!
   call finalize
 
End Program cns12
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function cns12_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Cns12_ReadMatrix
#endif
   Use casedata_num
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
   if ( casenum == 1 ) then
      curr(1)  = 1.0d0
      curr(2)  = 1.0d0
      curr(3)  = 1.0d0
   endif
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
   type(1) = 0
   rhs(1)  = scale
   type(2) = 0
   type(3) = 0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)  x(2)  x(3)
!  1:    1     2
!  2:          3     5
!  3:          4     6
!
   colsta(1) =  1
   colsta(2) =  2
   colsta(3) =  5
   colsta(4) =  7
   rowno(1)  =  1
   rowno(2)  =  1
   rowno(3)  =  2
   rowno(4)  =  3
   rowno(5)  =  2
   rowno(6)  =  3
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!       x(1)  x(2)  x(3)
!  1:    NL    NL
!  2:           L     L
!  3:           L     L
!
   nlflag(1) =  1
   nlflag(2) =  1
   nlflag(3) =  0
   nlflag(4) =  0
   nlflag(5) =  0
   nlflag(6) =  0
!
!  Value (Linear only)
!       x(1)  x(2)  x(3)
!  1:   NL    NL
!  2:          1     1
!  3:          1    -1
!
   value(3)  =  1.0d0
   value(4)  =  1.0d0
   value(5)  =  1.0d0
   value(6)  = -1.0d0
 
  cns12_readmatrix = 0 ! Return value means OK
 
end Function cns12_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function cns12_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                             n, nz, thread, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Cns12_FDEval
#endif
   use casedata_num
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
!
!  Row 1: the only nonlinear row: x*x
!
   if ( rowno .eq. 1 ) then
!
!  Mode = 1 or 3. Function value: G = P * Out
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = scale*x(1)*x(2)
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = scale*x(2)
         jac(2) = scale*x(1)
      endif
   endif
   cns12_fdeval = 0
 
end Function cns12_fdeval