evalerr01.f90

Go to the documentation of this file.

!> @file evalerr01.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!!
!! Model with function evaluation errors -- 01
!!
!! This is a CONOPT implementation of the GAMS model:
!!
!! @verbatim
!! variable x1, x2, x3, x4  ;
!! equation e1, e2, e3  ;
!!
!! e1 .. x1 + x2 =E= 1;
!!
!! e2 .. x1*log(x1) + x2*log(x2) + x3 - x4 =E= 0;
!!
!! e3 .. x1 + 2*x2 - sqr(x3) =E= 0;
!!
!! x1.l = 0.5; x2.l = 0.5;
!!
!! model EvalErr01 / all /;
!!
!! solve EvalErr01 using nlp minimizing x4;
!! @endverbatim
!!
!! The expected behavior is as follows:
!! 1. x4 is a post-triangular variable in eq2 and is ignored until a
!! feasible solution is found to the remaining constraints.
!! 2. The initial value of x3 is zero so the term sqr(x3) has derivative zero.
!! The initial basis will therefore consist of x1 and x2.
!! 3. Solving e1 and e3 w.r.t. x1 and x2 gives x1 = 2 and x2 = -1.
!! 4. Entering these values into e2 gives a log error.
!! 5. We should therefore expect Sstat = 5 (Domain violation) and
!! Mstat = 6 (Intermediate Infeasible).
!!
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
!> Main program. A simple setup and call of CONOPT
!!
Program evalerr01
 
   Use proginfo
   Use conopt
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: eval_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: eval_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
   Integer, External :: std_triord     ! Standard callback for triangular order
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Eval_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Eval_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_TriOrd
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
 
   call startup
!
!  Create and initialize a Control Vector
!
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 4 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 3 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 9 ) )  ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 3 ) )  !  of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) ) ! Minimize
   coi_error = max( coi_error, coidef_objvar( cntvect, 4 ) )  ! # of Objective variable
   coi_error = max( coi_error, coidef_optfile( cntvect, 'evalerr01.opt' ) )
   coi_error = max( coi_error, coidef_errlim( cntvect, 1000 ) ) ! Allow function evaluation errors
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, eval_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, eval_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
   coi_error = max( coi_error, coidef_triord( cntvect, std_triord     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Evalerr01 example. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 5 .or. mstat /= 6 ) then
      call flog( "Solver and Model Status was not as expected (5,6)", 1 )
   endif
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
!
!  Free solution memory
!
   call finalize
 
End Program evalerr01
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function eval_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Eval_ReadMatrix
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
!  The model uses defaults
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
!  Constraint 1: e1
!  Rhs = 1.0 and type Equality
!
   rhs(1)  = 1.0d0
   type(1) = 0
!
!  Constraint 2: e2
!  Rhs = 0.0 and type Equality
!
   type(2) = 0
!
!  Constraint 3: e3
!  Rhs = 0.0 and type Equality
!
   type(3) = 0
!
!  Initial values
!
   curr(1) = 0.5d0
   curr(2) = 0.5d0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)  x(2)  x(3)  x(4)
!  1:    1     4
!  2:    2     5     7     9
!  3:    3     6     8
!
   colsta(1) =  1
   colsta(2) =  4
   colsta(3) =  7
   colsta(4) =  9
   colsta(5) = 10
   rowno(1)  =  1
   rowno(2)  =  2
   rowno(3)  =  3
   rowno(4)  =  1
   rowno(5)  =  2
   rowno(6)  =  3
   rowno(7)  =  2
   rowno(8)  =  3
   rowno(9)  =  2
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!       x(1)  x(2)  x(3)   x(4)
!  1:    L     L
!  2:   NL    NL     L      L
!  3:    L     L    NL
!
   nlflag(1) =  0
   nlflag(2) =  1
   nlflag(3) =  0
   nlflag(4) =  0
   nlflag(5) =  1
   nlflag(6) =  0
   nlflag(7) =  0
   nlflag(8) =  1
   nlflag(9) =  0
!
!  Value (Linear only)
!       x(1)  x(2)  x(3)   x(4)
!  1:   1.0   1.0
!  2:   NL    NL    1.0   -1.0
!  3:   1.0   2.0   NL
!
   value(1)  =  1.d0
   value(3)  =  1.d0
   value(4)  =  1.d0
   value(6)  =  2.d0
   value(7)  =  1.d0
   value(9)  = -1.d0
 
  eval_readmatrix = 0 ! Return value means OK
 
end Function eval_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function eval_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                              n, nz, thread, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Eval_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
 
   eval_fdeval = 0
!
!  Row 2: e2
!
   if ( rowno .eq. 2 ) then
!
!  Mode = 1 or 3. G = x1*log(x1) + x2*log(x2)
!
      if ( x(1) <= 1.e-12 .or. x(2) <= 1.e-12 ) then
         errcnt = errcnt + 1
         Return
      Endif
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = x(1)*log(x(1)) + x(2)*log(x(2))
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = log(x(1)) + 1.0d0
         jac(2) = log(x(2)) + 1.0d0
      endif
   else if ( rowno .eq. 3 ) then
!
!  Mode = 1 or 3. G = sqr(x3)
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = x(3)*x(3)
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(3) = x(3)+x(3)
      endif
!
!  Row 1: The row is linear and will not be called
!
   else
      eval_fdeval = 1
   endif
 
end Function eval_fdeval