force02.f90

Go to the documentation of this file.

!> @file force02.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! This is a CONOPT implementation of the GAMS model:
!! 
!! @verbatim
!! set i / i1*i4 /;
!! variable x, z
!! positive variable y(i);
!! 
!! equation pre, force, objdef;
!! scalar rhs;
!! 
!! pre .. x =E= rhs;
!! force .. sum(i, i*y(i) ) - x =L= 0;
!! objdef .. sum(i, y(i) ) - z =E= 0;
!! 
!! Model m / all /
!! set case / c1*c5 /;
!! parameter rhsc(case) / c1 1.0, c2 5.0e-13, c3 0.0, c4 -5.0e-13, c5 -1 /
!! 
!! Loop(case,
!! rhs = rhsc(case);
!! solve m using lp maximizing z;
!! );
!! @endverbatim
!! 
!! The model status should be
!! c1 : Feasible (force is not forcing and y(1) = 1)
!! c2 : Feasible (force is forcing all y are zero)
!! c3 : Feasible (force is forcing all y are zero)
!! c4 : Feasible (force is forcing all y are zero)
!! c5 : Force is infeasible.
!! 
!! @verbatim
!! Loop(case,
!! rhs = rhsc(case);
!! solve m using lp minimizing z;
!! );
!! @endverbatim
!! 
!! The model status should be
!! c1 : Feasible (force is not forcing but all y's are still zero)
!! c2 : Feasible (force is forcing all y are zero)
!! c3 : Feasible (force is forcing all y are zero)
!! c4 : Feasible (force is forcing all y are zero)
!! c5 : Force is infeasible.
!! 
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
module force02data
   Integer, Parameter :: MaxCase = 5
   real*8, Parameter, dimension(MaxCase) :: caserhs = &
     (/ 1.0d0, 5.0d-13, 0.0d0, -5.0d-13, -1.0d0 /)
   Integer, Parameter, dimension(MaxCase) :: casemstat = &
     (/ 1, 1, 1, 1, 4 /)
   real*8, Parameter, dimension(MaxCase) :: caseobj1 = &
     (/ 1.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0 /)
   real*8, Parameter, dimension(MaxCase) :: caseobj2 = &
     (/ 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0 /)
   Integer :: casenum
end module force02data
 
!> Main program. A simple setup and call of CONOPT
!!
Program force02
 
   Use proginfo
   Use conopt
   Use force02data
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: force_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: force_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
   Integer, External :: std_triord     ! Standard callback for Forcengular order
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Force_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Force_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_TriOrd
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
 
   call startup
!
!  Create and initialize a Control Vector
!
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 6 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 3 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 11 ) ) ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 0 ) )  ! # of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, 1 ) )  ! Maximize
   coi_error = max( coi_error, coidef_objvar( cntvect, 6 ) )  ! Objective variable #
   coi_error = max( coi_error, coidef_optfile( cntvect, 'Force02.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, force_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, force_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
   coi_error = max( coi_error, coidef_triord( cntvect, std_triord     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
   DO casenum = 1, maxcase
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Force02 case',casenum,' - Maximize. Return code=',coi_error
 
      If ( coi_error /= 0 ) then
         call flog( "Errors encountered during solution", 1 )
      elseif ( stacalls == 0 .or. solcalls == 0 ) then
         call flog( "Status or Solution routine was not called", 1 )
      elseif ( sstat /= 1 .or. mstat /= casemstat(casenum) ) then
         call flog( "Solver and Model Status was not as expected", 1 )
      elseif ( mstat == 1 .and. abs( obj-caseobj1(casenum) ) > 0.000001d0 ) then
         call flog( "Incorrect objective returned", 1 )
      Elseif ( mstat == 1 ) Then
         Call checkdual( 'Force02', maximize )
      Elseif ( mstat == 4 ) Then
         Call checkdual( 'Force02', infeasible )
      endif
   EndDo ! end Casenum loop
!
!  Change direction of optimization and run the loop again
!
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) )  ! Minimize
   DO casenum = 1, maxcase
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Force02 case',casenum,' - Minimize. Return code=',coi_error
 
      If ( coi_error /= 0 ) then
         call flog( "Errors encountered during solution", 1 )
      elseif ( stacalls == 0 .or. solcalls == 0 ) then
         call flog( "Status or Solution routine was not called", 1 )
      elseif ( sstat /= 1 .or. mstat /= casemstat(casenum) ) then
         call flog( "Solver and Model Status was not as expected", 1 )
      elseif ( mstat == 1 .and. abs( obj-caseobj2(casenum) ) > 0.000001d0 ) then
         call flog( "Incorrect objective returned", 1 )
      Elseif ( mstat == 1 ) Then
         Call checkdual( 'Force02', minimize )
      Elseif ( mstat == 4 ) Then
         Call checkdual( 'Force02', infeasible )
      endif
   EndDo ! end Casenum loop
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
 
End Program force02
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function force_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Force_ReadMatrix
#endif
   Use force02data
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
!  The model uses defaults
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
!  Constraint 1: e1
!  Rhs = CaseRhs and type Equality
!
   rhs(1)  = caserhs(casenum)
   type(1) = 0
!
!  Constraint 2: e2
!  Rhs = 0.0 and type Less than or equal
!
   type(2) = 2
!
!  Constraint 3: e3
!  Rhs = 0.0 and type Equality
!
   type(3) = 0
!
!  Non-default Bounds
!
   lower(2) = 0.0d0
   lower(3) = 0.0d0
   lower(4) = 0.0d0
   lower(5) = 0.0d0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)  x(2)  x(3)  x(4)  x(5)  x(6)
!  1:    1
!  2:    2     3     5     7     9
!  3:          4     6     8    10     11
!
   colsta(1) =  1
   colsta(2) =  3
   colsta(3) =  5
   colsta(4) =  7
   colsta(5) =  9
   colsta(6) = 11
   colsta(7) = 12
   rowno(1)  =  1
   rowno(2)  =  2
   rowno(3)  =  2
   rowno(4)  =  3
   rowno(5)  =  2
   rowno(6)  =  3
   rowno(7)  =  2
   rowno(8)  =  3
   rowno(9)  =  2
   rowno(10) =  3
   rowno(11) =  3
!
!  Nonlinearity Structure: Model is linear
!
!
!  Value (Linear only)
!       x(1)  x(2)  x(3)  x(4)  x(5)  x(6)
!  1:   1.0
!  2:  -1.0   1.0   2.0   3.0   4.0
!  3:         1.0   1.0   1.0   1.0  -1.0
!
   value(1)  =  1.d0
   value(2)  = -1.d0
   value(3)  =  1.d0
   value(4)  =  1.d0
   value(5)  =  2.d0
   value(6)  =  1.d0
   value(7)  =  3.d0
   value(8)  =  1.d0
   value(9)  =  4.d0
   value(10) =  1.d0
   value(11) = -1.d0
 
  force_readmatrix = 0 ! Return value means OK
 
end Function force_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function force_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                              n, nz, thread, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Force_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
!
!  The model is linear and FDEval should not be called.
!
   force_fdeval = 1
 
end Function force_fdeval