ident22.f90

Go to the documentation of this file.

!> @file ident22.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!!
!! Model with identical variables, i.e. <code>a*xi =E= b*xj</code>.
!! Similar to ident21, but with bounds on the variables.
!! The bounds are not consistent with the identities
!! and they prevent the global minimum of zero.
!!
!! This is a CONOPT implementation of the GAMS model:
!!
!! @verbatim
!! variable x1, x2, x3, x4, x5;
!! equation e1, e2, e3, e4;
!!
!! e1.. x1 =E= x3;
!! e2.. x2 + x4 =E= 0;
!! e3.. x1 + 2*x2 =E= 1;
!! e4.. x5 =E= sqr(x1+x2+x3+x4);
!!
!! x1.lo = -1;
!! x4.lo = -0.4;
!! x2.lo = 0;
!!
!! model m / all /;
!! solve m using nlp minimizing x5;
!! @endverbatim
!!
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
!> Main program. A simple setup and call of CONOPT
!!
Program ident22
 
   Use proginfo
   Use conopt
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: ident_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: ident_fdeval     ! Function and Derivative evaluation routine
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Ident_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Ident_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
 
   call startup
!
!  Create and initialize a Control Vector
!
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 5 ) )
   coi_error = max( coi_error, coidef_numcon( cntvect, 4 ) )
   coi_error = max( coi_error, coidef_numnz( cntvect, 11 ) )
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 4 ) )
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) )        ! minimize
   coi_error = max( coi_error, coidef_objvar( cntvect, 5 ) )         ! Objective is x5
   coi_error = max( coi_error, coidef_optfile( cntvect, 'Ident22.opt'  ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, ident_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, ident_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Ident example 1. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( .not. ( sstat == 1 .and. mstat == 2 ) ) then
      call flog( "Solver or Model status was not as expected (1,2)", 1 )
   elseif ( abs( obj - 0.16d0 ) > 1.d-7 ) then
      call flog( "Incorrect objective returned", 1 )
   Else
      Call checkdual( 'Ident22', minimize )
   endif
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
!
!  Free solution memory
!
   call finalize
 
End Program ident22
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function ident_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Ident_ReadMatrix
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
 
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
   lower(1) = -1.0d0
   lower(2) = 0.0d0;
   lower(4) = -0.4d0
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
!  Constraints 1 to Nrow:
!  Rhs = Obs(i) and type Equality
!
   type(1) = 0
   type(2) = 0
   type(3) = 0
   type(4) = 0
   rhs(3)  = 1.0d0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!       x1  x2  x3  x4  x5
!  e1   1       7
!  e2       4       9
!  e3   2   5
!  e4   3   6   8  10  11
 
!  e1.. x1 =E= x3;
!  e2.. x2 + x4 =E= 0;
!  e3.. x1 + 2*x2 =E= 1;
!  e4.. x5 =E= sqr(x1+x2+x3+x4);
!       x1  x2  x3  x4  x5
!  e1   1.0    -1.0
!  e2       1.0     1.0
!  e3   1.0 2.0
!  e4   NL  NL  NL  NL  1.0
!
   colsta(1) = 1
   colsta(2) = 4
   colsta(3) = 7
   colsta(4) = 9
   colsta(5) = 11
   colsta(6) = 12
   rowno(1)  = 1; nlflag(1)  = 0; value(1) = 1.0d0
   rowno(2)  = 3; nlflag(2)  = 0; value(2) = 1.0d0
   rowno(3)  = 4; nlflag(3)  = 1;
   rowno(4)  = 2; nlflag(4)  = 0; value(4) = 1.0d0
   rowno(5)  = 3; nlflag(5)  = 0; value(5) = 2.0d0
   rowno(6)  = 4; nlflag(6)  = 1;
   rowno(7)  = 1; nlflag(7)  = 0; value(7) = -1.0d0
   rowno(8)  = 4; nlflag(8)  = 1;
   rowno(9)  = 2; nlflag(9)  = 0; value(9) = 1.0d0
   rowno(10) = 4; nlflag(10) = 1;
   rowno(11) = 4; nlflag(11) = 0; value(11) = 1.0d0
 
   ident_readmatrix = 0 ! Return value means OK
 
end Function ident_readmatrix
 
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function ident_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                             n, nz, thread, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Ident_FDEval
#endif
   Use ident
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
!
   if ( rowno .eq. 4 ) then
!
!  Mode = 1 or 3. Function value: -sqr(x1+x2+x3+x4)
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = -(x(1)+x(2)+x(3)+x(4))**2
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = -2.d0*(x(1)+x(2)+x(3)+x(4))
         jac(2) = -2.d0*(x(1)+x(2)+x(3)+x(4))
         jac(3) = -2.d0*(x(1)+x(2)+x(3)+x(4))
         jac(4) = -2.d0*(x(1)+x(2)+x(3)+x(4))
      endif
      ident_fdeval = 0
   else
      ident_fdeval = 1 ! Illegal row number
   endif
 
end Function ident_fdeval