lp10.f90

Go to the documentation of this file.

!> @file lp10.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! Test model lp10.gms -- case with an error
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
module caseconst
   real*8  :: case_c
end module caseconst
!> Main program. A simple setup and call of CONOPT
!!
Program lp10
 
   Use proginfo
   Use conopt
   Use caseconst
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: lp10_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Lp10_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
 
   Integer :: iter
!
!  Create and initialize a Control Vector
!
   call startup
 
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 5 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 2 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 7 ) )  ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 0 ) )  ! # of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) )  ! Minimize
   coi_error = max( coi_error, coidef_objvar( cntvect, 5 ) )  ! Objective is variable 5
   coi_error = max( coi_error, coidef_optfile( cntvect, 'lp10.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, lp10_readmatrix ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT4 Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   case_c = 1.0d0
   do iter = 1, 100
      case_c = case_c / 10.d0
      coi_error = coi_solve( cntvect )
      If ( coi_error /= 0 ) then
         call flog( "Errors encountered during solution", 1 )
      elseif ( stacalls == 0 .or. solcalls == 0 ) then
         call flog( "Status or Solution routine was not called", 1 )
      elseif ( sstat /= 1 ) then
         call flog( "Solver Status was 1 not as expected.", 1 )
      else
         if ( mstat == 3 ) then ! Unbounded
            if ( c_unbnd == 0 ) then
               call flog( "Unbounded model but count of unbounded variables was zero.", 1 )
            endif
         else if ( mstat == 1 ) then ! Optimal
            if ( c_unbnd /= 0 ) then
               call flog( "Optimal model but Count of unbounded variables was not zero.", 1 )
            Endif
            if ( case_c > 1.d-6 ) then
               call flog( "Optimal model but case_c > 1.d-6 should give unbounded.", 1 )
            endif
            exit
         else
            call flog( "Model Status was not as expected 3 or 1.", 1 )
         endif
      endif
   enddo
 
   write(*,*)
   write(*,*) 'End of lp10 example. Return code=',coi_error
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
!
!  Free solution memory
!
   call finalize
 
End Program lp10
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function lp10_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Lp10_ReadMatrix
#endif
   use caseconst
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
   lower(3) = 0.0d0
   lower(4) = 0.0d0
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
   type(1) = 0
   type(2) = 0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x1  x2  x3  x4  x5
!  1:    1       4       7
!  2:    2   3   5   6
!
   colsta(1) = 1
   colsta(2) = 3
   colsta(3) = 4
   colsta(4) = 6
   colsta(5) = 7
   colsta(6) = 8
   rowno(1)  = 1
   rowno(2)  = 2
   rowno(3)  = 2
   rowno(4)  = 1
   rowno(5)  = 2
   rowno(6)  = 2
   rowno(7)  = 1
!
!  Nonlinearity Structure: Not needed for a linear model
!
!  Value (Linear only)
!       x1  x2  x3  x4  x5
!  1:   -1      -1       1
!  2:   1   c    1  -1
!
   value(1)  = -1.d0
   value(2)  =  1.d0
   value(3)  =  case_c
   value(4)  = -1.d0
   value(5)  =  1.d0
   value(6)  = -1.d0
   value(7)  =  1.d0
 
  lp10_readmatrix = 0 ! Return value means OK
 
end Function lp10_readmatrix