nleq05.f90

Go to the documentation of this file.

!> @file nleq05.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! 
!! nonlinear function to bound conversion example 05
!! 
!! This is a CONOPT implementation of the GAMS model:
!! 
!! @verbatim
!! variable x1
!! equation e1;
!! 
!! e1 .. log(x1) =R= C;
!! 
!! x1.lo = 0.1; x1.up = 2;
!! model Nleq / all /;
!! solve Nleq using nlp maximizing x1;
!! @endverbatim
!! 
!! This model compares to Mono06 but we do not have any intervals
!! this time and feasibility / infeasibility is therefore local.
!! 
!! Where we have the following 9 cases:
!! @verbatim
!! 1:  =E= -3.0  ! Infeasible
!! 2:  =E=  0.5  ! Feasible, x1 = exp(0.5)
!! 3:  =E=  1.0  ! Infeasible
!! 4:  =L= -3.0  ! Infeasible
!! 5:  =L=  0.5  ! Feasible, x1 = exp(0.5)
!! 6:  =L=  1.0  ! Feasible, x1 = 2.0
!! 7:  =G= -3.0  ! feasible, x1 = 2.0
!! 8:  =G=  0.5  ! feasible, x1 = 2.0
!! 9:  =G=  1.0  ! Infeasible
!! @endverbatim
!! 
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
module nleq05data
   Integer, Parameter :: maxcase = 9
   real*8, Parameter, dimension(MaxCase) :: caserhs = &
     (/ -3.0d0, 0.5d0, 1.0d0, -3.0d0, 0.5d0, 1.0d0, -3.0d0, 0.5d0, 1.0d0 /)
   Integer, Parameter, dimension(MaxCase) :: casetype = &
     (/ 0, 0, 0, 2, 2, 2, 1, 1, 1 /)
   Integer, Parameter, dimension(MaxCase) :: casemstat = &
     (/ 5, 2, 5, 5, 2, 2, 2, 2, 5 /)
   real*8, Parameter, dimension(MaxCase) :: caseobj = &
     (/ 0.d0, exp(0.5d0), 0.0d0, 0.0d0, exp(0.5d0), 2.0d0, 2.0d0, 2.0d0, 0.0d0 /)
   Integer :: casenum
end module nleq05data
 
!> Main program. A simple setup and call of CONOPT
!!
Program nleq05
 
   Use proginfo
   Use coidef
   Use nleq05data
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: nleq_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: nleq_fdeval     ! Function and Derivative evaluation routine
                                        ! needed a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
   Integer, External :: std_triord     ! Standard callback for Nleqngular order
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Nleq_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Nleq_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_TriOrd
#endif
!
!  Control vector
!
   INTEGER :: numcallback
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
 
   call startup
!
!  Create and initialize a Control Vector
!
   numcallback = coidef_size()
   Allocate( cntvect(numcallback) )
   coi_error = coidef_inifort( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 1 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 1 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 1 ) )  ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 1 ) )  ! # of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, +1 ) ) ! Maximize
   coi_error = max( coi_error, coidef_objvar( cntvect, 1 ) )  ! Objective is variable 3
   coi_error = max( coi_error, coidef_optfile( cntvect, 'Nleq05.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, nleq_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, nleq_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
   coi_error = max( coi_error, coidef_triord( cntvect, std_triord     ) )
 
#if defined(LICENSE_INT_1) && defined(LICENSE_INT_2) && defined(LICENSE_INT_3) && defined(LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, license_int_1, license_int_2, license_int_3, license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
   DO casenum = 1, maxcase
!
!  Start CONOPT:
!
      coi_error = coi_solve( cntvect )
 
      write(*,*)
      write(*,*) 'End of Nleq05 example case',casenum,'. Return code=',coi_error
 
      If ( coi_error /= 0 ) then
         call flog( "Errors encountered during solution", 1 )
      elseif ( stacalls == 0 .or. solcalls == 0 ) then
         call flog( "Status or Solution routine was not called", 1 )
      elseif ( sstat /= 1 .or. mstat /= casemstat(casenum) ) then
         call flog( "Solver and Model Status was not as expected", 1 )
      elseif ( mstat == 1 .and. (abs( obj-caseobj(casenum) ) > 0.000001d0 ) ) then
         call flog( "Incorrect objective returned", 1 )
      Elseif ( mstat == 1 ) Then
         Call checkdual( 'Nleq05', maximize )
      Elseif ( mstat == 4 ) Then
         Call checkdual( 'Nleq05', infeasible )
      endif
 
   EndDo ! end Casenum loop
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
 
End Program nleq05
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function nleq_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Nleq_ReadMatrix
#endif
   Use nleq05data
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
!  The model uses defaults
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
!  Constraint 1: e1
!  Rhs = 10.0 and type Less than or Equal
!
   rhs(1)  = caserhs(casenum)
   type(1) = casetype(casenum)
!
   lower(1) = 0.1d0
   curr(1)  = 1.0d0
   upper(1) = 2.0
!
!  Information about the Jacobian. We use the standard method with
!  Rowno, Value, Nlflag and Colsta and we do not use Colno.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)
!  1:    1
!
   colsta(1) =  1
   colsta(2) =  2
   rowno(1)  =  1
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!       x(1)
!  1:    NL
!
   nlflag(1) =  1
!
!  Value (Linear only)
!       x(1)
!  1:   NL
!
  nleq_readmatrix = 0 ! Return value means OK
 
end Function nleq_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function nleq_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                              n, nz, thread, usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Nleq_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
!
!  Row 1: e1
!
   if ( rowno .eq. 1 ) then
!
!  Mode = 1 or 3. G = log(x1)
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = log(x(1))
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = 1.d0/x(1)
      endif
      nleq_fdeval = 0
   else
!
!  There are no other rows:
!
      nleq_fdeval = 1
   endif
 
end Function nleq_fdeval