pen02.f90

Go to the documentation of this file.

!> @file pen02.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!!
!! Test model pen02.gms -- a model with penalty pairs.
!!
!! Positive variables \f$x1, x2, x3, p, n\f$
!!
!! \f[
!! \min x1 + p + n
!! \f]
!! \f[
!! x1    + x2    + x3    = 6
!! \f]
!! \f[
!! x1^2 + x2^2 + x3^2 = 14
!! \f]
!! \f[
!! x1^3 + x2^3 + x3^3 = 36
!! \f]
!! \f[
!! x1    + x2^2 + x3^3 + p - n = 0
!! \f]
!!
!! Initial values in the first case x1 = x2 = x3 = 0.5;
!! With these values the first three constraints are parallel and we
!! will very likely end in a locally infeasible solution.
!!
!! Initial values in the next cases x1 = 0.2, x2 = 0.4, and x3 = 0.6;
!! In case 2 we stop after 1 iteration which means we are in Phase 0
!! in the internal model.
!! We test that the solution is relative to the large model.
!!
!! In case 3 we stop after 4 iteration which means we are in Phase 1
!! in the internal model. We should have duals.
!! We test that the solution is relative to the large model.
!!
!! In case 4 we solve the model to optimality.
!!
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
!> Main program. A simple setup and call of CONOPT
!!
Program pen02
 
   Use proginfo
   Use conopt
   Use casedata_num
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: pen02_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: pen02_fdeval     ! Function and Derivative evaluation routine
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Pen02_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Pen02_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
!
!  Create and initialize a Control Vector
!
   call startup
 
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 5 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 5 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect,17 ) )  ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 8 ) )  ! # of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) )  ! Minimize
   coi_error = max( coi_error, coidef_objcon( cntvect, 5 ) )  ! Objective is expression 5
   coi_error = max( coi_error, coidef_optfile( cntvect, 'pen02.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, pen02_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, pen02_fdeval ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT4 Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   casenum = 1
   coi_error = coi_solve( cntvect )
   If ( coi_error /= 0 ) then
      call flog( "Case 1: Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Case 1: Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 ) then
      call flog( "Case 1: Solver Status was not 1 as expected.", 1 )
   endif
!
!  Solve the second case -- max 1 iteration:
!
   stacalls = 0; solcalls = 0;
   casenum = 2
   coi_error = max( coi_error, coidef_itlim( cntvect, 1   ) )
   coi_error = coi_solve( cntvect )
   If ( coi_error /= 0 ) then
      call flog( "Case 2: Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Case 2: Status or Solution routine was not called", 1 )
   elseif ( sstat /= 2 ) then
      call flog( "Case 2: Solver Status was not 2 as expected.", 1 )
   endif
!
!  The third -- max 4 iterations:
!
   stacalls = 0; solcalls = 0;
   casenum = 3
   coi_error = max( coi_error, coidef_itlim( cntvect, 4   ) )
   coi_error = coi_solve( cntvect )
   If ( coi_error /= 0 ) then
      call flog( "Case 3: Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Case 3: Status or Solution routine was not called", 1 )
   elseif ( sstat /= 2 ) then
      call flog( "Case 3: Solver Status was not 2 as expected.", 1 )
   endif
!
!  And the fourth -- no practical iteration limit:
!
   stacalls = 0; solcalls = 0;
   casenum = 4
   coi_error = max( coi_error, coidef_itlim( cntvect, 10000   ) )
   coi_error = coi_solve( cntvect )
   If ( coi_error /= 0 ) then
      call flog( "Case 4: Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Case 4: Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 ) then
      call flog( "Case 4: Solver Status was 1 not as expected.", 1 )
   endif
 
   write(*,*)
   write(*,*) 'End of pen02 example. Return code=',coi_error
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
!
!  Free solution memory
!
   call finalize
 
End Program pen02
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function pen02_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Pen02_ReadMatrix
#endif
   use casedata_num
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
   lower(1) = 0.0d0
   lower(2) = 0.0d0
   lower(3) = 0.0d0
   lower(4) = 0.0d0
   lower(5) = 0.0d0
   if ( casenum == 1 ) Then
      curr(1) = 0.5d0
      curr(2) = 0.5d0
      curr(3) = 0.5d0
   Else
      curr(1) = 0.2d0
      curr(2) = 0.4d0
      curr(3) = 0.6d0
   Endif
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
   type(1) = 0
   type(2) = 0
   type(3) = 0
   type(4) = 0
   type(5) = 3
   rhs(1) =  6.d0
   rhs(2) = 14.d0
   rhs(3) = 36.d0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x1  x2  x3  x4  x5
!  1:    1   6  10
!  2:    2   7  11
!  3:    3   8  12
!  4:    4   9  13  14  16
!  5:    5          15  17
!
   colsta(1) = 1
   colsta(2) = 6
   colsta(3) =10
   colsta(4) =14
   colsta(5) =16
   colsta(6) =18
   rowno(1)  = 1
   rowno(2)  = 2
   rowno(3)  = 3
   rowno(4)  = 4
   rowno(5)  = 5
   rowno(6)  = 1
   rowno(7)  = 2
   rowno(8)  = 3
   rowno(9)  = 4
   rowno(10) = 1
   rowno(11) = 2
   rowno(12) = 3
   rowno(13) = 4
   rowno(14) = 4
   rowno(15) = 5
   rowno(16) = 4
   rowno(17) = 5
!
!  Nonlinearity Structure:
!
!       x1  x2  x3  x4  x5
!  1:    L   L   L
!  2:   NL  NL  NL
!  3:   NL  NL  NL
!  4:    L  NL  NL   L   L
!  5:    L           L   L
!
   nlflag(1)  = 0
   nlflag(2)  = 1
   nlflag(3)  = 1
   nlflag(4)  = 0
   nlflag(5)  = 0
   nlflag(6)  = 0
   nlflag(7)  = 1
   nlflag(8)  = 1
   nlflag(9)  = 1
   nlflag(10) = 0
   nlflag(11) = 1
   nlflag(12) = 1
   nlflag(13) = 1
   nlflag(14) = 0
   nlflag(15) = 0
   nlflag(16) = 0
   nlflag(17) = 0
!
!  Value (Linear only)
!       x1  x2  x3  x4  x5
!  1:    1   1   1
!  2:   NL  NL  NL
!  3:   NL  NL  NL
!  4:    1  NL  NL   1  -1
!  5:    1           1   1
!
   value(1)  =  1.d0
   value(4)  =  1.d0
   value(5)  =  1.d0
   value(6)  =  1.d0
   value(10) =  1.d0
   value(14) =  1.d0
   value(15) =  1.d0
   value(16) = -1.d0
   value(17) =  1.d0
 
  pen02_readmatrix = 0 ! Return value means OK
 
end Function pen02_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function pen02_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                             n, nz, thread, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Pen02_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
 
   pen02_fdeval = 0
   if ( rowno .eq. 1 ) then
!
!  Row 1: Linear
!
      pen02_fdeval = 1 ! This is an error
   elseif ( rowno .eq. 2 ) then
!
!  Row 2: x1**2 + x2**2 + x3**2
!
!  Mode = 1 or 3: Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g = x(1)**2 + x(2)**2 + x(3)**2
      endif
!
!  Mode = 2 or 3: Derivatives
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = 2.d0*x(1)
         jac(2) = 2.d0*x(2)
         jac(3) = 2.d0*x(3)
      endif
   elseif ( rowno .eq. 3 ) then
!
!  Row 3: x1**3 + x2**3 + x3**3
!
!  Mode = 1 or 3: Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g = x(1)**3 + x(2)**3 + x(3)**3
      endif
!
!  Mode = 2 or 3: Derivatives
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = 3.d0*x(1)**2
         jac(2) = 3.d0*x(2)**2
         jac(3) = 3.d0*x(3)**2
      endif
   elseif ( rowno .eq. 4 ) then
!
!  Row 4: x1 + x2**2 + x3**3 where first term is linear
!
!  Mode = 1 or 3: Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g = x(2)**2 + x(3)**3
      endif
!
!  Mode = 2 or 3: Derivatives
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(2) = 2.d0*x(2)
         jac(3) = 3.d0*x(3)**2
      endif
   elseif ( rowno .eq. 4 ) then
!
!  Row = 5: The row is linear and will not be called.
!
      pen02_fdeval = 1 ! This is an error
   endif
 
end Function pen02_fdeval