post.f90

Go to the documentation of this file.

!> @file post.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! 
!! This is a CONOPT implementation of the GAMS model:
!! 
!! @verbatim
!! variable x1, x2, x3, x4, obj;
!! equations e1, p1, objdef;
!! 
!! scalar value;
!! 
!! e1 .. sqr(x1) + sqr(x2) =E= 1;
!! 
!! p1 .. sqr(x1-1) + sqr(x2-2) + value*x3 + x4 =E= 0;
!! 
!! objdef .. sqr(x3-1) + sqr(x4-1) - obj =E= 0;
!! 
!! model m / all /;
!! m.optfile=1;
!! x1.l = 0.5; x2.l = 0.5;
!! option limrow = 0, limcol = 0;
!! option sysout = on;
!! set iter / it1*it3 /;
!! parameter rep(*,iter);
!! loop( iter,
!! value = 100*power(0.1, ord(iter) );
!! solve m using nlp minimizing obj;
!! rep('x1',iter) = x1.l;
!! rep('x2',iter) = x2.l;
!! rep('x3',iter) = x3.l;
!! rep('x4',iter) = x4.l;
!! rep('obj',iter) = obj.l;
!! );
!! display rep;
!! @endverbatim
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
!> Main program. A simple setup and call of CONOPT
!!
Program postpiv
 
   Use proginfo
   Use conopt
   Use casedata_num
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: post_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: post_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
   Integer, External :: post_option    ! Option defining callback routine
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Post_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Post_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Post_Option
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
!
!  Create and initialize a Control Vector
!
   call startup
 
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 5 ) )  ! 4 variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 3 ) )  ! 3 constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 9 ) )  ! 9 nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 6 ) )  ! 6 of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) ) ! Minimize
   coi_error = max( coi_error, coidef_objvar( cntvect, 5 ) )  ! Objective is variable 5
   coi_error = max( coi_error, coidef_optfile( cntvect, 'postpiv.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, post_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, post_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
   coi_error = max( coi_error, coidef_option( cntvect, post_option     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   DO casenum = 1, 3
      coi_error = coi_solve( cntvect )
 
      write(*,*)
      write(*,*) 'End of PostPiv example with Casenum=',casenum,'. Return code=',coi_error
 
      If ( coi_error /= 0 ) then
         call flog( "Errors encountered during solution", 1 )
      elseif ( stacalls == 0 .or. solcalls == 0 ) then
         call flog( "Status or Solution routine was not called", 1 )
      elseif ( sstat /= 1 .or. mstat /= 2 ) then
         call flog( "Solver and Model Status was not as expected (1,2)", 1 )
      Else
         Call checkdual( 'PostPiv', minimize )
      endif
      if ( casenum == 1 ) Then      ! Variable X3 must be post-triangular and therefore basic and X4 superbasic
         if ( xbasc(3) /= bsbasic .or. xbasc(4) /= bssuper ) Then
            call flog( "Basis / Superbasis status was not as expected", 1 )
         Endif
      elseif ( casenum == 3 ) Then  ! Variable X4 must be post-triangular and therefore basic and X3 superbasic
         if ( xbasc(4) /= bsbasic .or. xbasc(3) /= bssuper ) Then
            call flog( "Basis / Superbasis status was not as expected", 1 )
         Endif
      Endif
   Enddo
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
 
End Program postpiv
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function post_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Post_ReadMatrix
#endif
   Use casedata_num
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
!  All variables are free.
!  X1 and X2 have initial value 0.5
!
   curr(1)  = 0.5d0
   curr(2)  = 0.5d0
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
!  Constraint 1
!  Rhs = 1 and type Equality
!
   rhs(1)  = 1.0d0
   type(1) = 0
!
!  Constraint 2
!  Rhs = 0 and type Equality
!
   type(2) = 0
!
!  Constraint 3
!  Rhs = 0 and type Equality
!
   type(3) = 0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)  x(2)  x(3)  x(4)  x(5)
!  1:    1     3
!  2:    2     4     5     7
!  3:                6     8     9
!
   colsta(1) =  1
   colsta(2) =  3
   colsta(3) =  5
   colsta(4) =  7
   colsta(5) =  9
   colsta(6) = 10
   rowno(1)  =  1
   rowno(2)  =  2
   rowno(3)  =  1
   rowno(4)  =  2
   rowno(5)  =  2
   rowno(6)  =  3
   rowno(7)  =  2
   rowno(8)  =  3
   rowno(9)  =  3
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!       x(1)  x(2)  x(3)  x(4)  x(5)
!  1:    NL    NL
!  2:    NL    NL    L     L
!  3:               NL    NL     L
!
   nlflag(1) =  1
   nlflag(2) =  1
   nlflag(3) =  1
   nlflag(4) =  1
   nlflag(5) =  0
   nlflag(6) =  1
   nlflag(7) =  0
   nlflag(8) =  1
   nlflag(9) =  0
!
!  Value (Linear only)
!       x(1)  x(2)  x(3)  x(4)  x(5)
!  1:    NL    NL
!  2:    NL    NL    S     1         where s changes from case to case
!  3:               NL    NL    -1
!
   value(5)  =  100.d0 * 0.1d0**casenum ! 10, 1, and 0.1 in the three cases
   value(7)  =  1.d0
   value(9)  = -1.d0
 
  post_readmatrix = 0 ! Return value means OK
 
end Function post_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function post_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                             n, nz, thread, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Post_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
!
!  Row 1: e1 .. sqr(x1) + sqr(x2) =E= 1;
!
   if ( rowno .eq. 1 ) then
!
!  Mode = 1 or 3. Function value: G = P * Out
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = x(1)*x(1) + x(2)*x(2)
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = 2.d0*x(1)
         jac(2) = 2.d0*x(2)
      endif
!
!  Row 2: p1 .. sqr(x1-1) + sqr(x2-2) + value*x3 + x4 =E= 0;
!
   elseif ( rowno .eq. 2 ) then
!
!  Mode = 1 or 3: Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g = (x(1)-1.d0)**2 + (x(2)-2.d0)**2
      endif
!
!  Mode = 2 or 3: Derivatives
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = 2.d0*(x(1)-1.d0)
         jac(2) = 2.d0*(x(2)-2.d0)
      endif
!
!  Row = 3: objdef .. sqr(x3-1) + sqr(x4-1) - obj =E= 0;
!
   elseif ( rowno .eq. 3 ) then
!
!  Mode = 1 or 3: Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g = (x(3)-1.d0)**2 + (x(4)-1.d0)**2
      endif
!
!  Mode = 2 or 3: Derivatives
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(3) = 2.d0*(x(3)-1.d0)
         jac(4) = 2.d0*(x(4)-1.d0)
      endif
   endif
   post_fdeval = 0
 
end Function post_fdeval
 
 
!>  Sets runtime options
!!
!! @include{doc} option_params.dox
Integer Function post_option( ncall, rval, ival, lval, usrmem, name )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Post_Option
#endif
   integer  ncall, ival, lval
   character(Len=*) :: name
   real*8   rval
   real*8   usrmem(*)                                  ! optional user memory
 
   Select case (ncall)
   case (1)
      name = 'lotria'
      ival = 1  ! Report on triangular equations
   case default
      name = ' '
   end Select
   post_option = 0
 
end Function post_option