postmo01.f90

Go to the documentation of this file.

!> @file postmo01.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! 
!! Model with derivatives that become constant after other variables are fixed.
!! 
!! This is a CONOPT implementation of the GAMS model:
!! 
!! @verbatim
!! e1: log(x1) =E= x2;
!! e2: exp(x3) =E= x1;
!! max x2
!! 0.01 <= x1 x1.l = 1
!! -1.0 <= x2 <= 1; x2.l = 0
!! x3.l = 0;
!! @endverbatim
!! 
!! The bounds on x2 prevent e1 from being posttriangular immediately. However, due to
!! the monotonicity the bounds can be transferred to x1. Similarly, the bounds on x1
!! can be moved to x2 and the model ends with one variable and no constraints.
!! 
!! The transfer of bounds work as follows:
!! e1: the inverval `-1 <= x2 <= 1` is transferred to `0.368 = exp(-1) <= x1 <= exp(1) = 2.718`
!! that both are tighter than the input bounds.
!! e2: the inverval `exp(-1) <= x1 <= exp(1)` from before is transferred to `-1 <= x3 <= 1`
!! that again is tighter that the input bounds.
!! 
!! The expected solution is `x2=1` (at upper bound), `x1=exp(x2)=exp(1)`, and `x3= log(x1) = 1`;
!! 
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
!> Main program. A simple setup and call of CONOPT
!!
Program postmo01
 
   Use proginfo
   Use coidef
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: con_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: con_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: con_fdinterval ! Function and Derivative evaluation routine
                                       ! optional for a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Con_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Con_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Con_FDInterval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
!
!  Create and initialize a Control Vector
!
   call startup
 
   coi_error = coi_createfort( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 3 ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 2 ) )  ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 4 ) )  ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 2 ) )  ! # of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, 1 ) )  ! Maximize
   coi_error = max( coi_error, coidef_objvar( cntvect, 2 ) )  ! Objective is variable 2
   coi_error = max( coi_error, coidef_optfile( cntvect, 'postmo01.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, con_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, con_fdeval     ) )
   coi_error = max( coi_error, coidef_fdinterval( cntvect, con_fdinterval ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(LICENSE_INT_1) && defined(LICENSE_INT_2) && defined(LICENSE_INT_3) && defined(LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, license_int_1, license_int_2, license_int_3, license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of postmo01 example. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 2 ) then
      call flog( "Solver and Model Status was not as expected (1,2)", 1 )
   elseif ( abs( obj-1.0d0 ) > 0.000001d0 ) then
      call flog( "Incorrect objective returned", 1 )
   Else
      Call checkdual( 'postmo01', maximize )
   endif
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
 
End Program postmo01
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function con_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Con_ReadMatrix
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
   lower(1) = 0.01d0; curr(1) = 1.0d0
   lower(2) = -1.0d0; curr(2) = 0.0d0; upper(2) = 1.0d0
                      curr(3) = 0.0d0
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
   type(1) = 0
   type(2) = 0
!
!  Information about the Jacobian. We use the standard method with
!  Rowno, Value, Nlflag and Colsta and we do not use Colno.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)  x(2)  x(3)
!  1:    1     3
!  2:    2           4
!  e1: log(x1) =E= x2;
!  e2: exp(x3) =E= x1;
!
   colsta(1) =  1
   colsta(2) =  3
   colsta(3) =  4
   colsta(4) =  5
   rowno(1)  =  1
   rowno(2)  =  2
   rowno(3)  =  1
   rowno(4)  =  2
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!       x(1)  x(2)  x(3)
!  1:    NL     L
!  2:    L          NL
!
   nlflag(1) =  1
   nlflag(2) =  0
   nlflag(3) =  0
   nlflag(4) =  1
!
!  Value (Linear only)
!       x(1)  x(2)  x(3)
!  1:    NL   -1.0
!  2:   -1.0         NL
!
   value(2)  = -1.d0
   value(3)  = -1.d0
 
  con_readmatrix = 0 ! Return value means OK
 
end Function con_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function con_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                             n, nz, thread, usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Con_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
   if ( rowno .eq. 1 ) then
!
!  e1: log(x1) =E= x2;
!
!  Mode = 1 or 3: Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g = log(x(1))
      endif
!
!  Mode = 2 or 3: Derivatives
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = 1.0d0/x(1)
      endif
      con_fdeval = 0
   else if ( rowno .eq. 2 ) then
!
!  e2: exp(x3) =E= x1;
!
!  Mode = 1 or 3: Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g = exp(x(3))
      endif
!
!  Mode = 2 or 3: Derivatives
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(3) = exp(x(3))
      endif
      con_fdeval = 0
   Else
      con_fdeval = 1 ! Should not happen
   endif
 
end Function con_fdeval
 
 
!>  Evaluating nonlinear functions and derivatives on an interval. Used in preprocessing
!!
!! @include{doc} fdinterval_params.dox
Integer Function con_fdinterval( XMIN, XMAX, GMIN, GMAX,  &
                                 JMIN, JMAX, ROWNO, JCNM, &
                                 MODE, PINF, N, NJ, USRMEM )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Con_FDInterval
#endif
   Implicit None
   INTEGER, Intent(IN)                   :: rowno, mode, n, nj
   INTEGER, Dimension(NJ), Intent(IN)    :: jcnm
   real*8,  Dimension(N), Intent(IN)     :: xmin, xmax
   real*8,  Intent(IN OUT)               :: gmin, gmax
   real*8,  Dimension(N), Intent(IN OUT) :: jmin, jmax
   real*8,  Intent(IN)                   :: pinf
   real*8,  Intent(IN OUT)               :: usrmem(*)
 
   if ( rowno .eq. 1 ) then
!
!  e1: log(x1) =E= x2;
!
!  Mode = 1 or 3. Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         gmin = log(xmin(1))
         gmax = log(xmax(1))
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jmin(1) = 1.0d0/xmax(1)
         jmax(1) = 1.0d0/xmin(1)
      endif
      con_fdinterval = 0
   else if ( rowno .eq. 2 ) then
!
!  e2: exp(x3) =E= x1;
!
!  Mode = 1 or 3. Function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         gmin = exp(xmin(3))
         gmax = exp(xmax(3))
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jmin(3) = exp(xmin(3))
         jmax(3) = exp(xmax(3))
      endif
      con_fdinterval = 0
   else
!
!  There are no other rows:
!
      con_fdinterval = 1
   endif
 
end Function con_fdinterval