range10.f90

Go to the documentation of this file.

!> @file range10.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!!
!! Range10:
!! Model where some constraints can be combined into a single equality constraint.
!!
!! This is a CONOPT implementation of the GAMS model:
!!
!! @verbatim
!! positive variable x1, x2, x3, x4, x5
!! equation e1, e2, e3, e4;
!! e1.. x1 + x2        x4      =L= 0;
!! e2..           x3 + x4      =L= 2;
!! e3..          2x3 +2x4      =G= 4;
!! e4..           x3      + x5 =E= 3;
!! e5..                x4 + x5 =L= 2;
!! x4.up = 1;
!! minimize x3;
!! @endverbatim
!!
!! e2 and e3 are combined into an equality constraint. After e1 has forced x1, x2, and x4
!! to zero we have a derived equality with row count 1 and it should translate into x3 being
!! fixed.
!! We have added some extra rows to prevent x3 from becoming post-traingular as in range09.
!!
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
!> Main program. A simple setup and call of CONOPT
!!
Program range10
 
   Use proginfo
   Use conopt
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: rng_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Rng_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
!
!  Create and initialize a Control Vector
!
   call startup
 
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 5 ) )  ! 5 variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 5 ) )  ! 5 constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 11 ) )  ! 11 nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 0 ) )  ! 0 of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) )  ! Minimize
   coi_error = max( coi_error, coidef_objvar( cntvect, 3 ) )  ! Objective is variable 3
   coi_error = max( coi_error, coidef_optfile( cntvect, 'Range10.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, rng_readmatrix ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Range10 example A. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution A", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called A", 1 )
   elseif ( sstat /= 1 .or. mstat /= 1 ) then ! Linear model
      call flog( "Solver and Model Status was not as expected (1,1) A", 1 )
   elseif ( abs( obj-2.0d0 ) > 0.000001d0 ) then
      call flog( "Incorrect objective returned A", 1 )
   Else
      Call checkdual( 'Range10A', minimize )
   endif
!
!  We now reverse the direction of optimization and check that the dual still
!  are OK
!
   coi_error = max( coi_error, coidef_optdir( cntvect, +1 ) )  ! Maximize
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Range10 example B. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution B", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called B", 1 )
   elseif ( sstat /= 1 .or. mstat /= 1 ) then ! Linear model
      call flog( "Solver and Model Status was not as expected (1,1) B", 1 )
   elseif ( abs( obj-2.0d0 ) > 0.000001d0 ) then
      call flog( "Incorrect objective returned B", 1 )
   Else
      Call checkdual( 'Range10B', maximize )
   endif
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
!
!  Free solution memory
!
   call finalize
 
End Program range10
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function rng_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Rng_ReadMatrix
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
   lower(1) = 0.0d0
   lower(2) = 0.0d0
   lower(3) = 0.0d0
   lower(4) = 0.0d0
   lower(5) = 0.0d0
   upper(4) = 1.0d0
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
   type(1) = 2
   type(2) = 2; rhs(2) = 2.0d0
   type(3) = 1; rhs(3) = 4.0d0
   type(4) = 0; rhs(4) = 3.0d0
   type(5) = 2; rhs(5) = 2.0d0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  e4..           x3      + x5 =E= 3;
!  e5..                x4 + x5 =L= 2;
!  Indices
!       x(1)  x(2)  x(3)  x(4)  x(5)
!  1:    1     2            6
!  2:                 3     7
!  3:                 4     8
!  4:                 5         10
!  5:                       9   11
!
   colsta(1) =  1
   colsta(2) =  2
   colsta(3) =  3
   colsta(4) =  6
   colsta(5) = 10
   colsta(6) = 12
   rowno(1)  =  1
   rowno(2)  =  1
   rowno(3)  =  2
   rowno(4)  =  3
   rowno(5)  =  4
   rowno(6)  =  1
   rowno(7)  =  2
   rowno(8)  =  3
   rowno(9)  =  5
   rowno(10) =  4
   rowno(11) =  5
!
!  Nonlinearity Structure: Model is linear and nlfalg is not needed
!
!  e4..           x3      + x5 =E= 3;
!  e5..                x4 + x5 =L= 2;
!  Value (Linear only)
!       x(1)  x(2)  x(3)  x(4)  x(5)
!  1:   +1    +1           +1
!  2:                +1    +1
!  3:                +2    +2
!  4:                +1         +1
!  5:                      +1   +1
!
   value(1)  = 1.d0
   value(2)  = 1.d0
   value(3)  = 1.d0
   value(4)  = 2.d0
   value(5)  = 1.d0
   value(6)  = 1.d0
   value(7)  = 1.d0
   value(8)  = 2.d0
   value(9)  = 1.d0
   value(10) = 1.d0
   value(11) = 1.d0
 
  rng_readmatrix = 0 ! Return value means OK
 
end Function rng_readmatrix