tria03.f90

Go to the documentation of this file.

!> @file tria03.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!!
!! Triangular Demo model 03
!!
!! This is a CONOPT implementation of the GAMS model:
!!
!! @verbatim
!! variable x1, x2, x3, x4  ;
!! equation e1, e2, e3  ;
!!
!! e1 .. x1 + power(x2,3) =e= 5;
!!
!! e2 .. sqr(x2)          =e= 4;
!!
!! e3 .. x3               =e= x2 + x1 + sqr(x4);
!!
!! model tria03 / all /;
!! @endverbatim
!!
!! The preprocessor will not solve this model given the initial values.
!! Initially, equation e2 should be solved with respect to variable x2,
!! but the derivative in the initial point is 0 and the nonlinear term
!! is not monotone so CONOPT cannot determine how to change x2.
!! Therefore, the preprocessor is interrupted without solving e2.
!! However, CONOPT itself should be able to solve the model using
!! the new negative curvature method.
!!
!! @verbatim
!! solve tria03 using nlp minimizing x3;
!! @endverbatim
!!
!! We try again, this time with a positive initial value for x2 = +10:
!! x2.l = 10;
!!
!! @verbatim
!! solve tria03 using nlp minimizing x3;
!! @endverbatim
!!
!! And we try with a negative initial value for x2 = -10:
!! x2.l = -10;
!!
!! @verbatim
!! solve tria03 using nlp minimizing x3;
!! @endverbatim
!!
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
!> Main program. A simple setup and call of CONOPT
!!
Program tria03
 
   Use proginfo
   Use conopt
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: tria_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: tria_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tria_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tria_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
!
!  Create and initialize a Control Vector
!
   call startup
 
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 4 ) )  ! 3 variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 3 ) )  ! 3 constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 7 ) )  ! 6 nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 3 ) )  ! 3 of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, -1 ) ) ! Minimize
   coi_error = max( coi_error, coidef_objvar( cntvect, 3 ) )  ! Objective is variable 3
   coi_error = max( coi_error, coidef_optfile( cntvect, 'tria03.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, tria_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, tria_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of First Call. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 2 ) then
      call flog( "Solver and Model Status was not as expected (1,2)", 1 )
! No Objective test
   Else if ( mstat == 2 ) then
      Call checkdual( 'Tria03', minimize )
   Else if ( mstat == 5 ) then
      Call checkdual( 'Tria03', infeasible )
   endif
 
   stacalls = 0; solcalls = 0
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Second Call. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 2 ) then
      call flog( "Solver and Model Status was not as expected (1,2)", 1 )
   elseif ( abs( obj-(-1.0d0) ) > 0.000001d0 ) then
      call flog( "Incorrect objective returned", 1 )
   Else
      Call checkdual( 'Tria03', minimize )
   endif
 
   stacalls = 0; solcalls = 0
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Third Call. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 2 ) then
      call flog( "Solver and Model Status was not as expected (1,2)", 1 )
   elseif ( abs( obj-11.0d0 ) > 0.000001d0 ) then
      call flog( "Incorrect objective returned", 1 )
   Else
      Call checkdual( 'Tria03', minimize )
   endif
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
!
!  Free solution memory
!
   call finalize
 
End Program tria03
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function tria_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tria_ReadMatrix
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
!  The model uses defaults, except for x2 where the starting value is
!  default in first call, +10 in the second, and -10 in the third
!
   integer, save :: ncall = 0
   if ( ncall == 0 ) then
      ncall = 1
   else if ( ncall == 1 ) then
      curr(2) = +10.d0; ncall = 2
   else if ( ncall == 2 ) then
      curr(2) = -10.d0; ncall = 3
   else
      tria_readmatrix = 1; return
   endif
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
!  Constraint 1: e1
!  Rhs = 5.0 and type Equality
!
   rhs(1)  = 5.0d0
   type(1) = 0
!
!  Constraint 2: e2
!  Rhs = 4.0 and type Equality
!
   rhs(2)  = 4.0d0
   type(2) = 0
!
!  Constraint 3: e3
!  Rhs = 0.0 and type Equality
!
   type(3) = 0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)  x(2)  x(3)  x(4)
!  1:    1     3
!  2:          4
!  3:    2     5     6     7
!
   colsta(1) =  1
   colsta(2) =  3
   colsta(3) =  6
   colsta(4) =  7
   colsta(5) =  8
   rowno(1)  =  1
   rowno(2)  =  3
   rowno(3)  =  1
   rowno(4)  =  2
   rowno(5)  =  3
   rowno(6)  =  3
   rowno(7)  =  3
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!       x(1)  x(2)  x(3)  x(4)
!  1:    L     NL
!  2:          NL
!  3:    L     L     L     NL
!
   nlflag(1) =  0
   nlflag(2) =  0
   nlflag(3) =  1
   nlflag(4) =  1
   nlflag(5) =  0
   nlflag(6) =  0
   nlflag(7) =  1
!
!  Value (Linear only)
!       x(1)  x(2)  x(3)  x(4)
!  1:   1.0    NL
!  2:         5.0
!  3:  -1.0  -1.0   1.0    NL
!
   value(1)  =  1.d0
   value(2)  = -1.d0
   value(4)  =  5.d0
   value(5)  = -1.d0
   value(6)  =  1.d0
 
  tria_readmatrix = 0 ! Return value means OK
 
end Function tria_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function tria_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                              n, nz, thread, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tria_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
!
!  Row 1: e1 .. x1 + power(x2,3) =e= 5;
!
   if ( rowno .eq. 1 ) then
!
!  Mode = 1 or 3. G = power(x2,3)
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = x(2)*x(2)*x(2)
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(2) = 3.d0*x(2)*x(2)
      endif
      tria_fdeval = 0
!
!  Row 2: e2 .. sqr(x2)          =e= 4;
!
   elseif ( rowno .eq. 2 ) then
!
!  Mode = 1 or 3. G = sqr(x2)
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = x(2)*x(2)
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(2) = 2.d0*x(2)
      endif
      tria_fdeval = 0
!
!  Row 2: e3 .. x3               =e= x2 + x1 + sqr(x4);
!
   elseif ( rowno .eq. 3 ) then
!
!  Mode = 1 or 3. G = -sqr(x4)
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = -x(4)*x(4)
      endif
!
!  Mode = 2 or 3: Derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(4) = -2.d0*x(4)
      endif
      tria_fdeval = 0
   Else
!
!  Illegal row number
!
      tria_fdeval = 1
   endif
 
end Function tria_fdeval