tutoriali.f90

Go to the documentation of this file.

!> @file tutoriali.f90
!! @ingroup FORT1THREAD_EXAMPLES
!! @brief This model is a revision of Tutorial in which we have added a
!! an initialization callback for the First derivative, Tut_FDEvalIni.
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
#if defined(_WIN32) && !defined(_WIN64)
#define dec_directives_win32
#endif
 
Module var
!
!  Declare copies of the optimization variables. The values are
!  communicated from FdevalIni to Fdeval.
!
   real*8            :: l, inp, out, p
!
!  declare parameters and their data values.
!
   real*8, parameter :: w    = 1.0d0
   real*8, parameter :: l0   = 0.1d0
   real*8, parameter :: pinp = 1.0d0
   real*8, parameter :: al   = 0.16d0
   real*8, parameter :: ak   = 2.0d0
   real*8, parameter :: ainp = 0.16d0
   real*8, parameter :: rho  = 1.0d0
   real*8, parameter :: k    = 4.0d0
   real*8            :: hold1, hold2, hold3 ! intermediate results
End Module var
 
!> Main program. A simple setup and call of CONOPT
!!
Program tutorial
 
   Use proginfo
   Use conopt
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: tut_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: tut_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: tut_fdevalini  ! Function and Derivative initialization routine.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tut_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tut_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tut_FDEvalIni
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
!
!  Create and initialize a Control Vector
!
   call startup
 
   coi_error = coi_create( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 4 ) )  ! 4 variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 3 ) )  ! 3 constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, 9 ) )  ! 9 nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 4 ) )  ! 4 of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, 1 ) )  ! Maximize
   coi_error = max( coi_error, coidef_objcon( cntvect, 1 ) )  ! Objective is constraint 1
   coi_error = max( coi_error, coidef_optfile( cntvect, 'tutoriali.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, tut_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, tut_fdeval     ) )
   coi_error = max( coi_error, coidef_fdevalini( cntvect, tut_fdevalini  ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(CONOPT_LICENSE_INT_1) && defined(CONOPT_LICENSE_INT_2) && defined(CONOPT_LICENSE_INT_3) && defined(CONOPT_LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, conopt_license_int_1, conopt_license_int_2, conopt_license_int_3, conopt_license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Tutorial example. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 2 ) then
      call flog( "Solver and Model Status was not as expected (1,2)", 1 )
   elseif ( abs( obj-0.572943d0 ) > 0.000001d0 ) then
      call flog( "Incorrect objective returned", 1 )
   Else
      Call checkdual( 'Tutorial', maximize )
   endif
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
!
!  Free solution memory
!
   call finalize
 
End Program tutorial
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function tut_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tut_ReadMatrix
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
!  Lower bound on L   = X(1) = 0.1 and initial value = 0.5:
!
   lower(1) = 0.1d0
   curr(1)  = 0.5d0
!
!  Lower bound on INP = X(2) = 0.1 and initial value = 0.5:
!
   lower(2) = 0.1d0
   curr(2)  = 0.5d0
!
!  Lower bound on OUT = X(3) and P = X(4) are both 0 and the
!  default initial value of 0 is used:
!
   lower(3) = 0.d0
   lower(4) = 0.d0
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
!  Constraint 1 (Objective)
!  Rhs = -0.1 and type Non binding
!
   rhs(1)  = -0.1d0
   type(1) = 3
!
!  Constraint 2 (Production Function)
!  Rhs = 0 and type Equality
!
   type(2) = 0
!
!  Constraint 3 (Price equation)
!  Rhs = 4.0 and type Equality
!
   rhs(3)  = 4.d0
   type(3) = 0
!
!  Information about the Jacobian. CONOPT expects a columnwise
!  representation in Rowno, Value, Nlflag and Colsta.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
!  Indices
!       x(1)  x(2)  x(3)  x(4)
!  1:    1     3     5     8
!  2:    2     4     6
!  3:                7     9
!
   colsta(1) =  1
   colsta(2) =  3
   colsta(3) =  5
   colsta(4) =  8
   colsta(5) = 10
   rowno(1)  =  1
   rowno(2)  =  2
   rowno(3)  =  1
   rowno(4)  =  2
   rowno(5)  =  1
   rowno(6)  =  2
   rowno(7)  =  3
   rowno(8)  =  1
   rowno(9)  =  3
!
!  Nonlinearity Structure: L = 0 are linear and NL = 1 are nonlinear
!       x(1)  x(2)  x(3)  x(4)
!  1:    L     L     NL    NL
!  2:    NL    NL    L
!  3:                L     L
!
   nlflag(1) =  0
   nlflag(2) =  1
   nlflag(3) =  0
   nlflag(4) =  1
   nlflag(5) =  1
   nlflag(6) =  0
   nlflag(7) =  0
   nlflag(8) =  1
   nlflag(9) =  0
!
!  Value (Linear only)
!       x(1)  x(2)  x(3)  x(4)
!  1:   -1    -1     NL    NL
!  2:    NL    NL    -1
!  3:                 1     2
!
   value(1)  = -1.d0
   value(3)  = -1.d0
   value(6)  = -1.d0
   value(7)  =  1.d0
   value(9)  =  2.d0
 
  tut_readmatrix = 0 ! Return value means OK
 
end Function tut_readmatrix
 
!>  Initialises the function and derivative evaluation. Called each time the point of interest changes
!!
!! @include{doc} fdevalini_params.dox
Integer function tut_fdevalini( x, rowlist, mode, listsize, numthread, ignerr, errcnt, numvar, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tut_FDEvalIni
#endif
   Use var
   implicit none
   integer, intent (in)                        :: numvar    ! number of variables
   integer, intent (in)                        :: listsize  ! number of elements in rowlist
   integer, intent (in)                        :: numthread ! number of threads for following FDEval loop
   real*8,  intent (in), dimension(numvar)     :: x         ! vector of current solution values
   integer, intent (in), dimension(listsize)   :: rowlist ! The rows that will be called in this point
   integer, intent (in)                        :: mode   ! evaluation mode: 1 = function value
                                                         ! 2 = derivatives, 3 = both
   integer, intent (in)                        :: ignerr ! if 1 then errors can be ignored as long
                                                         ! as errcnt is incremented
   integer, intent (in out)                    :: errcnt ! error counter to be incremented in case
                                                         ! of function evaluation errors.
   real*8   usrmem(*)                                    ! optional user memory
!
!  move the optimization variables from the x vector to the variables
!  in module Var. They will then be used in FDEval
!
   l   = x(1)
   inp = x(2)
   out = x(3)
   p   = x(4)
!
!  compute some common terms
!
   hold1 = (al*l**(-rho) + ak*k**(-rho) + ainp*inp**(-rho))
   hold2 = hold1 ** ( -1.d0/rho )
   hold3  = hold2 / hold1
 
   tut_fdevalini = 0
   End Function tut_fdevalini
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
integer function tut_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                             numvar, nz, thread, usrmem )
#ifdef dec_directives_win32
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Tut_FDEval
#endif
   Use var
   implicit none
   integer, intent (in)                        :: numvar ! number of variables
   integer, intent (in)                        :: rowno  ! number of the row to be evaluated
   integer, intent (in)                        :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(numvar) :: x      ! vector of current solution values
   real*8,  intent (in out)                    :: g      ! constraint value
   real*8,  intent (in out), dimension(numvar) :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)     :: jcnm   ! list of variables that appear nonlinearly
                                                         ! in this row. ffor information only.
   integer, intent (in)                        :: mode   ! evaluation mode: 1 = function value
                                                         ! 2 = derivatives, 3 = both
   integer, intent (in)                        :: ignerr ! if 1 then errors can be ignored as long
                                                         ! as errcnt is incremented
   integer, intent (in out)                    :: errcnt ! error counter to be incremented in case
                                                         ! of function evaluation errors.
   integer, intent (in)                        :: thread
   real*8   usrmem(*)                                    ! optional user memory
!
!  row 1: the objective function is nonlinear
!
   if ( rowno .eq. 1 ) then
!
!  mode = 1 or 3. function value: g = p * out
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g    = p * out
      endif
!
!  mode = 2 or 3: derivative values:
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(3) = p     ! derivative w.r.t. out = x(3)
         jac(4) = out   ! derivative w.r.t. p   = x(4)
      endif
!
!  row 2: the production function is nonlinear
!
   elseif ( rowno .eq. 2 ) then
!
!  mode = 1 or 3: function value
!
      if ( mode .eq. 1 .or. mode .eq. 3 ) then
         g = hold2
      endif
!
!  mode = 2 or 3: derivatives
!
      if ( mode .eq. 2 .or. mode .eq. 3 ) then
         jac(1) = hold3 * al   * l   ** (-rho-1.d0) ! derivative w.r.t. l   = x(1)
         jac(2) = hold3 * ainp * inp ** (-rho-1.d0) ! derivative w.r.t. inp = x(2)
      endif
!
!  row = 3: the row is linear and will not be called.
!
   endif
   tut_fdeval = 0
 
end function tut_fdeval