vpost01.f90

Go to the documentation of this file.

!> @file vpost01.f90
!! @ingroup FORT1THREAD_EXAMPLES
!!
!! 
!! This is a CONOPT implementation of the GAMS model:
!! 
!! @verbatim
!! set i / i1*i5 /
!! b / b1*b2 /
!! parameter a(i,b)
!! positive variable x(i), y(i), z(i), v(b), obj;
!! equation e1(i), e2(i), e3(i), objdef
!! e1(i) .. x(i)               + sum(b, a(i,b)*v(b)) =E= 1*ord(i);
!! e2(i) .. x(i) + y(i)        - sum(b, a(i,b)*v(b)) =E= 2*ord(i);
!! e3(i) .. x(i) + y(i) + z(i) + sum(b, a(i,b)*v(b)) =E= 3*ord(i);
!! objdef .. obj =E= sum(b, ord(b)*v(b) );
!! x.up(i) = 10; y.up(i) = 20; z.up(i) = 30; v.up(b) = 40;
!! @endverbatim
!! 
!! For fixed values of the variables v the model is recursive. Used to
!! test various initialization procedures.
!! 
!!
!! For more information about the individual callbacks, please have a look at the source code.
 
Module vpost01data
   integer, Parameter :: ni = 5
   integer, Parameter :: nb = 2
   real*8,  Dimension(Ni,Nb) :: a
End Module vpost01data
 
!> Main program. A simple setup and call of CONOPT
!!
Program vpost01
 
   Use proginfo
   Use coidef
   Use vpost01data
   implicit None
!
!  Declare the user callback routines as Integer, External:
!
   Integer, External :: vp_readmatrix ! Mandatory Matrix definition routine defined below
   Integer, External :: vp_fdeval     ! Function and Derivative evaluation routine
                                       ! needed a nonlinear model.
   Integer, External :: std_status     ! Standard callback for displaying solution status
   Integer, External :: std_solution   ! Standard callback for displaying solution values
   Integer, External :: std_message    ! Standard callback for managing messages
   Integer, External :: std_errmsg     ! Standard callback for managing error messages
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: VP_ReadMatrix
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: VP_FDEval
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Status
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Solution
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_Message
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: Std_ErrMsg
#endif
!
!  Control vector
!
   INTEGER :: numcallback
   INTEGER, Dimension(:), Pointer :: cntvect
   INTEGER :: coi_error
!
!  Misc local variables
!
   Integer :: i, k
!
!  Initialize Vpost01Data for the model
!
   do i = 1, ni
      do k = 1, nb
         a(i,k) = 0.1d0*i/ni*k*(-1)**(i+k)
      enddo
   enddo
!
!  Create and initialize a Control Vector
!
   call startup
 
   numcallback = coidef_size()
   Allocate( cntvect(numcallback) )
   coi_error = coidef_inifort( cntvect )
!
!  Tell CONOPT about the size of the model by populating the Control Vector:
!
   coi_error = max( coi_error, coidef_numvar( cntvect, 3*ni+nb ) )  ! # variables
   coi_error = max( coi_error, coidef_numcon( cntvect, 3*ni+1 ) )   ! # constraints
   coi_error = max( coi_error, coidef_numnz( cntvect, ni*(6+3*nb)+nb ) ) ! # nonzeros in the Jacobian
   coi_error = max( coi_error, coidef_numnlnz( cntvect, 0 ) )        ! # of which are nonlinear
   coi_error = max( coi_error, coidef_optdir( cntvect, 1 ) )        ! Maximize
   coi_error = max( coi_error, coidef_objcon( cntvect, 3*ni+1 ) )   ! Objective is constraint #
   coi_error = max( coi_error, coidef_optfile( cntvect, 'vpost01.opt' ) )
!
!  Tell CONOPT about the callback routines:
!
   coi_error = max( coi_error, coidef_readmatrix( cntvect, vp_readmatrix ) )
   coi_error = max( coi_error, coidef_fdeval( cntvect, vp_fdeval     ) )
   coi_error = max( coi_error, coidef_status( cntvect, std_status     ) )
   coi_error = max( coi_error, coidef_solution( cntvect, std_solution   ) )
   coi_error = max( coi_error, coidef_message( cntvect, std_message    ) )
   coi_error = max( coi_error, coidef_errmsg( cntvect, std_errmsg     ) )
 
#if defined(LICENSE_INT_1) && defined(LICENSE_INT_2) && defined(LICENSE_INT_3) && defined(LICENSE_TEXT)
   coi_error = max( coi_error, coidef_license( cntvect, license_int_1, license_int_2, license_int_3, license_text) )
#endif
 
   If ( coi_error .ne. 0 ) THEN
      write(*,*)
      write(*,*) '**** Fatal Error while loading CONOPT Callback routines.'
      write(*,*)
      call flog( "Skipping Solve due to setup errors", 1 )
   ENDIF
!
!  Save the solution so we can check the duals:
!
   do_allocate = .true.
!
!  Start CONOPT:
!
   coi_error = coi_solve( cntvect )
 
   write(*,*)
   write(*,*) 'End of Vpost01 example. Return code=',coi_error
 
   If ( coi_error /= 0 ) then
      call flog( "Errors encountered during solution", 1 )
   elseif ( stacalls == 0 .or. solcalls == 0 ) then
      call flog( "Status or Solution routine was not called", 1 )
   elseif ( sstat /= 1 .or. mstat /= 1 ) then
      call flog( "Solver and Model Status was not as expected (1,1)", 1 )
   Else
      do i = 1, ni
         if ( abs(uprim(i)-i) > 1.e-7 .or. abs(uprim(ni+i)-2*i) > 1.e-7 .or. &
              abs(uprim(ni+ni+i)-3*i) > 1.e-7 ) Then
            call flog( "Incorrect activity level for an equation.", 1 )
         endif
      enddo
      Call checkdual( 'Vpost01', maximize )
   endif
 
   if ( coi_free(cntvect) /= 0 ) call flog( "Error while freeing control vector",1)
 
   call flog( "Successful Solve", 0 )
 
End Program vpost01
!
! ============================================================================
!  Define information about the model:
!
 
!>  Define information about the model
!!
!! @include{doc} readMatrix_params.dox
Integer Function vp_readmatrix( lower, curr, upper, vsta, type, rhs, esta,      &
                                 colsta, rowno, value, nlflag, n, m, nz,  &
                                 usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: VP_ReadMatrix
#endif
   use vpost01data
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: m      ! number of constraints
   integer, intent (in)                      :: nz     ! number of nonzeros
   real*8,  intent (in out), dimension(n)    :: lower  ! vector of lower bounds
   real*8,  intent (in out), dimension(n)    :: curr   ! vector of initial values
   real*8,  intent (in out), dimension(n)    :: upper  ! vector of upper bounds
   integer, intent (in out), dimension(n)    :: vsta   ! vector of initial variable status
                                                       ! (not defined here)
   integer, intent (out),    dimension(m)    :: type   ! vector of equation types
   integer, intent (in out), dimension(m)    :: esta   ! vector of initial equation status
                                                       ! (not defined here)
   real*8,  intent (in out), dimension(m)    :: rhs    ! vector of right hand sides
   integer, intent (in out), dimension(n+1)  :: colsta ! vector with start of column indices
   integer, intent (out),    dimension(nz)   :: rowno  ! vector of row numbers
   integer, intent (in out), dimension(nz)   :: nlflag ! vector of nonlinearity flags
   real*8,  intent (in out), dimension(nz)   :: value  ! vector of matrix values
   real*8   usrmem(*)                                  ! optional user memory
!
   integer i, j, k
!
!  Information about Variables:
!  Default: Lower = -Inf, Curr = 0, and Upper = +inf.
!  Default: the status information in Vsta is not used.
!
!  Lower bound = 0 on all variables
!
   do i = 1, n
      lower(i) = 0.0d0
   enddo
   do i = 1, ni
      upper(i) = 10.0d0
      upper(ni+i) = 20.0d0
      upper(ni+ni+i) = 30.0d0
   enddo
   do j = 1, nb
      upper(3*ni+j) = 40.d0
   enddo
!
!  Information about Constraints:
!  Default: Rhs = 0
!  Default: the status information in Esta and the function
!           value in FV are not used.
!  Default: Type: There is no default.
!           0 = Equality,
!           1 = Greater than or equal,
!           2 = Less than or equal,
!           3 = Non binding.
!
   do i = 1, ni
      rhs(i) = i
      rhs(ni+i) = 2*i
      rhs(ni+ni+i) = 3*i
   enddo
   do i = 1, 3*ni
      type(i) = 0
   enddo
!
!  Constraint 3*ni+1 (Objective)
!  Rhs = 0 and type Non binding
!
   type(3*ni+1) = 3
!  positive variable x(i), y(i), z(i), v(b), obj;
!  equation e1(i), e2(i), e3(i), objdef
!  e1(i) .. x(i)               + sum(b, a(i,b)*v(b)) =E= 1*ord(i);
!  e2(i) .. x(i) + y(i)        - sum(b, a(i,b)*v(b)) =E= 2*ord(i);
!  e3(i) .. x(i) + y(i) + z(i) + sum(b, a(i,b)*v(b)) =E= 3*ord(i);
!  objdef .. obj =E= sum(b, ord(b)*v(b) );
!
!  Information about the Jacobian. We use the standard method with
!  Rowno, Value, Nlflag and Colsta and we do not use Colno.
!
!  Colsta = Start of column indices (No Defaults):
!  Rowno  = Row indices
!  Value  = Value of derivative (by default only linear
!                                derivatives are used)
!  Nlflag = 0 for linear and 1 for nonlinear derivative
!           (not needed for completely linear models)
!
   k = 1
   do i = 1, ni ! x variables
      colsta(i) = k
      rowno(k) = i
      value(k) = 1.d0
      k        = k + 1
      rowno(k) = ni+i
      value(k) = 1.d0
      k        = k + 1
      rowno(k) = ni+ni+i
      value(k) = 1.d0
      k        = k + 1
   enddo
   do i = 1, ni ! y variables
      colsta(ni+i) = k
      rowno(k) = ni+i
      value(k) = 1.d0
      k        = k + 1
      rowno(k) = ni+ni+i
      value(k) = 1.d0
      k        = k + 1
   enddo
   do i = 1, ni ! z variables
      colsta(ni+ni+i) = k
      rowno(k) = ni+ni+i
      value(k) = 1.d0
      k        = k + 1
   enddo
   do j = 1, nb
      colsta(3*ni+j) = k
      do i = 1, ni
         rowno(k) = i
         value(k) = a(i,j)
         k        = k + 1
      enddo
      do i = 1, ni
         rowno(k) = ni+i
         value(k) = -a(i,j)
         k        = k + 1
      enddo
      do i = 1, ni
         rowno(k) = ni+ni+i
         value(k) = a(i,j)
         k        = k + 1
      enddo
      rowno(k) = 3*ni+1
      value(k) = j
      k        = k + 1
   enddo
   colsta(3*ni+nb+1) = k
 
   vp_readmatrix = 0 ! Return value means OK
 
end Function vp_readmatrix
!
!==========================================================================
!  Compute nonlinear terms and non-constant Jacobian elements
!
 
!>  Compute nonlinear terms and non-constant Jacobian elements
!!
!! @include{doc} fdeval_params.dox
Integer Function vp_fdeval( x, g, jac, rowno, jcnm, mode, ignerr, errcnt, &
                            n, nz, thread, usrmem )
#if defined(itl)
!DEC$ ATTRIBUTES STDCALL, REFERENCE, NOMIXED_STR_LEN_ARG :: VP_FDEval
#endif
   implicit none
   integer, intent (in)                      :: n      ! number of variables
   integer, intent (in)                      :: rowno  ! number of the row to be evaluated
   integer, intent (in)                      :: nz     ! number of nonzeros in this row
   real*8,  intent (in),     dimension(n)    :: x      ! vector of current solution values
   real*8,  intent (in out)                  :: g      ! constraint value
   real*8,  intent (in out), dimension(n)    :: jac    ! vector of derivatives for current constraint
   integer, intent (in),     dimension(nz)   :: jcnm   ! list of variables that appear nonlinearly
                                                       ! in this row. Ffor information only.
   integer, intent (in)                      :: mode   ! evaluation mode: 1 = function value
                                                       ! 2 = derivatives, 3 = both
   integer, intent (in)                      :: ignerr ! if 1 then errors can be ignored as long
                                                       ! as errcnt is incremented
   integer, intent (in out)                  :: errcnt ! error counter to be incremented in case
                                                       ! of function evaluation errors.
   integer, intent (in)                      :: thread
   real*8   usrmem(*)                                  ! optional user memory
 
   vp_fdeval = 1 ! this routine should never be called for a linear model
 
end Function vp_fdeval